I had to replace some special TI characters wit PC equivalents. Below is a table of the
replacements.
-> store
<= less than or equal to
>= greater than or equal to
!= not equal to
-  minus sign for negative numbers
_  list sign
O  the ball, actually the small square from the catalog

:                                                   This makes the program appear in AShell
ClrHome                                             Clear the screen
Output(2,5,"SQUASH 1"                               Print some text
Output(4,1,"----------------                        
Output(6,5,"MADE BY                                 
Output(7,1,"THOMAS TEN CATE                         
Pause                                               Wait for a keypress
Lbl GO                                              Start of the game
ClrHome                                             Clear the screen
8->X                                                X is the horizontal ball coordinate
4->Y                                                Y is the vertical ball coordinate
-1->V                                               V is the vertical ball speed
2randInt(0,1)-1->H                                  H is the horizontal ball speed
100->D                                              D is the loop delay
0->S                                                S is the score
8->R                                                R is the left of the racket
Output(8,R,"==                                      Draw the racket
Repeat Y>=8                                         Repeat until the ball gets to the bottom
X->O                                                O is the previous horizontal ball coordinate
Y->P                                                P is the previous vertical ball coordinate
X+H->X                                              Move the ball
Y+V->Y                                              
Output(1,1,S                                        Draw the score
Output(Y,X,"O                                       Draw the new ball
Output(P,O,"                                        Erase the old ball
getKey->I                                           Get a keypress
If I=24 and R>=1                                    If left was pressed and the racket isn't on
                                                    the left already...
Then                                                
R->P                                                Save the previous racket position
R-2->R                                              Move the racket
If R<1                                              If it goes out of the screen...
1->R                                                Move it back in
Output(8,P,"                                        Erase the previous racket
Output(8,R,"==                                      Draw the new one
If D>0                                              Decrease the delay to speed up the ball
D-5->D                                              
End                                                 
If I=26 and R<=13                                   If right was pressed and the racket isn't on
Then                                                the right already...                        
R->P                                                                                           
R+2->R                                              Save the previous racket position          
If R>15                                             Move the racket                            
15->R                                               If it goes out of the screen...            
Output(8,P,"                                        Move it back in                            
Output(8,R,"==                                      Erase the previous racket                  
If D>0                                              Draw the new one                           
D-5->D                                              Decrease the delay to speed up the ball    
End                                                                                            
If X+H<=1 or X+H>=16                                If the ball hits a wall...
-H->H                                               Make it turn around
If Y+V<=1                                           If the ball hits the ceiling...
-V->V                                               Make it turn around
If Y+V>=7 and X+H>=R and X+H<=R+1                   If the ball hits the racket...
Then                                                
-V->V                                               Make it turn around
S+1->S                                              Increase the score
If X+H=R and H>0 or X+H=R+1 and H<0                 If it hits a corner of the racket...
-H->H                                               Make it turn around
End                                                 
For(I,0,D                                           Run the delay loop so the game doesn't go too
End                                                 fast
End                                                 
ClrHome                                             Clear the screen
1->dim(_SQU1                                        Set hiscore list, if not set already
If S>_SQU1(1                                        If a new hiscore is made...
Then                                                
Disp "CONGRATULATIONS!                              Print some text
Disp "NEW HISCORE!                                  
Disp "PREVIOUS:                                     
Output(3,11,_SQU1(1                                 
Disp "NEW:                                          
Output(4,11,S                                       
S->_SQU1(1                                          
Else                                                If no new hiscore is made...
Disp "YOUR SCORE IS","","WHAT'S WRONG","WITH YOU?   Print some other text
Output(2,1,S                                        
End                                                 
For(I,0,1000                                        Delay
End                                                 
Disp "ANOTHER GAME?","ENTER=YES,","ANY OTHER KEY=NO Ask for another game
0->I                                                
Repeat I                                            Wait until they press a key
getKey->I                                           
End                                                 
If I=105                                            If Enter was pressed...
Goto GO                                             Play again
ClrHome                                             Clear the screen